stk-code_catmod/data/shaders/skinning.vert

#ifdef GL_ES
uniform mat4 ModelMatrix;
uniform mat4 InverseModelMatrix;
uniform vec2 texture_trans;
#else
uniform mat4 ModelMatrix =
    mat4(1., 0., 0., 0.,
         0., 1., 0., 0.,
         0., 0., 1., 0.,
         0., 0., 0., 1.);
uniform mat4 InverseModelMatrix =
    mat4(1., 0., 0., 0.,
         0., 1., 0., 0.,
         0., 0., 1., 0.,
         0., 0., 0., 1.);

uniform vec2 texture_trans = vec2(0., 0.);
#endif
uniform int skinning_offset;

layout(location = 0) in vec3 Position;
layout(location = 1) in vec3 Normal;
layout(location = 2) in vec4 Color;
layout(location = 3) in vec4 Data1;
layout(location = 4) in vec4 Data2;
layout(location = 5) in ivec4 Joint;
layout(location = 6) in vec4 Weight;

out vec3 nor;
out vec3 tangent;
out vec3 bitangent;
out vec2 uv;
out vec4 color;

#stk_include "utils/getworldmatrix.vert"

void main(void)
{
    mat4 TransposeInverseModelView =  transpose(InverseModelMatrix * InverseViewMatrix);
    vec4 idle_position = vec4(Position, 1.);
    vec4 idle_normal = vec4(Normal, 0.);
    vec4 skinned_position = vec4(0.);
    vec4 skinned_normal = vec4(0.);

    // Note : For normal we assume no scale factor in bone (otherwise we'll have to compute inversematrix for each bones...)
    vec4 single_bone_influenced_position;
    vec4 single_bone_influenced_normal;

    // First bone:
    single_bone_influenced_position = joint_matrices[clamp(Joint[0] + skinning_offset, 0, MAX_BONES)] * idle_position;
    single_bone_influenced_position /= single_bone_influenced_position.w;
    single_bone_influenced_normal = joint_matrices[clamp(Joint[0] + skinning_offset, 0, MAX_BONES)] * idle_normal;
    skinned_position += Weight[0] * single_bone_influenced_position;
    skinned_normal += Weight[0] * single_bone_influenced_normal;

    // Second bone:
    single_bone_influenced_position = joint_matrices[clamp(Joint[1] + skinning_offset, 0, MAX_BONES)] * idle_position;
    single_bone_influenced_position /= single_bone_influenced_position.w;
    single_bone_influenced_normal = joint_matrices[clamp(Joint[1] + skinning_offset, 0, MAX_BONES)] * idle_normal;
    skinned_position += Weight[1] * single_bone_influenced_position;
    skinned_normal += Weight[1] * single_bone_influenced_normal;

    // Third bone:
    single_bone_influenced_position = joint_matrices[clamp(Joint[2] + skinning_offset, 0, MAX_BONES)] * idle_position;
    single_bone_influenced_position /= single_bone_influenced_position.w;
    single_bone_influenced_normal = joint_matrices[clamp(Joint[2] + skinning_offset, 0, MAX_BONES)] * idle_normal;
    skinned_position += Weight[2] * single_bone_influenced_position;
    skinned_normal += Weight[2] * single_bone_influenced_normal;

    // Fourth bone:
    single_bone_influenced_position = joint_matrices[clamp(Joint[3] + skinning_offset, 0, MAX_BONES)] * idle_position;
    single_bone_influenced_position /= single_bone_influenced_position.w;
    single_bone_influenced_normal = joint_matrices[clamp(Joint[3] + skinning_offset, 0, MAX_BONES)] * idle_normal;
    skinned_position += Weight[3] * single_bone_influenced_position;
    skinned_normal += Weight[3] * single_bone_influenced_normal;

    gl_Position = ProjectionMatrix * ViewMatrix * ModelMatrix * skinned_position;
    // Keep orthogonality
    nor = (TransposeInverseModelView * skinned_normal).xyz;
    // Keep direction
    tangent = (ViewMatrix * ModelMatrix * vec4(Data1.z, Data1.w, Data2.x, 0.)).xyz;
    bitangent = (ViewMatrix * ModelMatrix * vec4(Data2.y, Data2.z, Data2.w, 0.)).xyz;

    uv = vec2(Data1.x + texture_trans.x, Data1.y + texture_trans.y);
    color = Color.zyxw;
}