media-sound/carla: add 2.5.5

media-sound/carla/Manifest

@@ -1 +1,2 @@
 DIST carla-2.5.4.tar.gz 11530440 BLAKE2B 6b4aaca799a3d435dbde9ce4cbf98147578ab416ec78a563c3c5b0654d69dcd52c251924b753dfc07ce6c6b74d57d69f82fc65cb8e120ed6c352ee48f4f465e8 SHA512 0bee1b450d832fafa035694f16fdae0509a2836449da875f1fe6e81adb2bbd4747e8c42e516c3896d0af03f50a47c1d3b63119bd321d10464c1c5e57645461b4
+DIST carla-2.5.5.tar.gz 11528560 BLAKE2B fd34d827eea5fb4b7a9fcd57827adde9fae1f0fe2ee02fcccfc4b2d0f72a31872f52956b32455666471cf573fcd04abe3d432c3d38407c6dabe8f95287da388c SHA512 93d0fd7c97956446701328f4b98db508a64df9ae6f476871ba7c1ec3f7cc420c206622a01ce5aec2e98079a714264dac5f3f662e0c3d0fad83cc1f1dbeac119a

media-sound/carla/carla-2.5.5.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit python-single-r1 xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/falkTX/Carla.git"
+	EGIT_SUBMODULES=() # Prevent Carla-Plugins from installing
+else
+	SRC_URI="https://github.com/falkTX/Carla/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	MY_PN="Carla"
+	MY_P="${MY_PN}-${PV}"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Fully-featured audio plugin host, supports many audio drivers and plugin formats"
+HOMEPAGE="https://kx.studio/Applications:Carla"
+LICENSE="GPL-2 LGPL-3"
+SLOT="0"
+IUSE="alsa gtk gtk2 opengl osc pulseaudio rdf sf2 sndfile X"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/PyQt5[gui,opengl?,svg,widgets,${PYTHON_USEDEP}]')
+	virtual/jack
+	alsa? ( media-libs/alsa-lib )
+	gtk? ( x11-libs/gtk+:3 )
+	gtk2? ( x11-libs/gtk+:2 )
+	osc? (
+		media-libs/liblo
+		media-libs/pyliblo
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	rdf? ( dev-python/rdflib )
+	sf2? ( media-sound/fluidsynth )
+	sndfile? ( media-libs/libsndfile )
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="${DEPEND}"
+
+src_prepare() {
+	sed -i -e "s|exec \$PYTHON|exec ${PYTHON}|" \
+		data/carla \
+		data/carla-control \
+		data/carla-database \
+		data/carla-jack-multi \
+		data/carla-jack-single \
+		data/carla-patchbay \
+		data/carla-rack \
+		data/carla-settings || die "sed failed"
+	sed -i "s;/share/appdata;/share/metainfo;g" "${S}/Makefile" || die "sed failed"
+	default
+}
+
+src_compile() {
+	myemakeargs=(
+		LIBDIR="/usr/$(get_libdir)"
+		SKIP_STRIPPING=true
+		HAVE_FFMPEG=false
+		HAVE_ZYN_DEPS=false
+		HAVE_ZYN_UI_DEPS=false
+		HAVE_QT4=false
+		HAVE_QT5=true
+		HAVE_PYQT5=true
+		DEFAULT_QT=5
+		HAVE_ALSA=$(usex alsa true false)
+		HAVE_FLUIDSYNTH=$(usex sf2 true false)
+		HAVE_GTK2=$(usex gtk2 true false)
+		HAVE_GTK3=$(usex gtk true false)
+		HAVE_LIBLO=$(usex osc true false)
+		HAVE_PULSEAUDIO=$(usex pulseaudio true false)
+		HAVE_SNDFILE=$(usex sndfile true false)
+		HAVE_X11=$(usex X true false)
+	)
+
+	# Print which options are enabled/disabled
+	make features PREFIX="/usr" "${myemakeargs[@]}"
+
+	emake PREFIX="/usr" "${myemakeargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" "${myemakeargs[@]}" install
+	if ! use osc; then
+		find "${D}/usr" -iname "carla-control*" | xargs rm
+	fi
+}