From 3dfa5f381ac7b7735404ee1304c06f0c01419ff7 Mon Sep 17 00:00:00 2001
From: Ryan Fox <flewkey@2a03.party>
Date: Thu, 6 Jul 2023 17:41:38 -0700
Subject: [PATCH] media-gfx/opentoonz: fix build, add 1.7.1

---
 media-gfx/opentoonz/Manifest               |  1 +
 media-gfx/opentoonz/opentoonz-1.7.1.ebuild | 82 ++++++++++++++++++++++
 media-gfx/opentoonz/opentoonz-9999.ebuild  |  3 +-
 3 files changed, 85 insertions(+), 1 deletion(-)
 create mode 100644 media-gfx/opentoonz/Manifest
 create mode 100644 media-gfx/opentoonz/opentoonz-1.7.1.ebuild

diff --git a/media-gfx/opentoonz/Manifest b/media-gfx/opentoonz/Manifest
new file mode 100644
index 0000000..f234154
--- /dev/null
+++ b/media-gfx/opentoonz/Manifest
@@ -0,0 +1 @@
+DIST opentoonz-1.7.1.tar.gz 52852616 BLAKE2B 6a9dc8ca4e13384c550386348a06ac2741a26b1467d9cea22defb3be4bb47ac72727e2ab870027c05f4fc269753c7ce77932e813f535e48d2199f33d2fdba97f SHA512 e33df315b945510c2dbc5aef34b86fa20db571a3196888a1940f3dbb4c5340b8b57cd659abee456e49fc8f4f3d10b6ecfeccc7770ec3193ee3f5e60dad6fe5cf
diff --git a/media-gfx/opentoonz/opentoonz-1.7.1.ebuild b/media-gfx/opentoonz/opentoonz-1.7.1.ebuild
new file mode 100644
index 0000000..0c80381
--- /dev/null
+++ b/media-gfx/opentoonz/opentoonz-1.7.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/opentoonz/opentoonz.git"
+else
+	SRC_URI="https://github.com/opentoonz/opentoonz/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An open-source full-featured 2D animation creation software"
+HOMEPAGE="https://opentoonz.github.io/"
+LICENSE="BSD libtiff"
+SLOT="0"
+
+DEPEND="
+	app-arch/lz4:=
+	>=dev-libs/boost-1.55.0:=
+	dev-libs/lzo:2
+	>=dev-qt/qtcore-5.9:5
+	>=dev-qt/qtgui-5.9:5
+	>=dev-qt/qtmultimedia-5.9:5[widgets]
+	>=dev-qt/qtnetwork-5.9:5
+	>=dev-qt/qtopengl-5.9:5
+	>=dev-qt/qtprintsupport-5.9:5
+	>=dev-qt/qtscript-5.9:5
+	>=dev-qt/qtserialport-5.9:5
+	>=dev-qt/qtsvg-5.9:5
+	>=dev-qt/qtwidgets-5.9:5
+	>=dev-qt/qtxml-5.9:5
+	media-libs/freeglut
+	media-libs/freetype:2
+	media-libs/glew:=
+	media-libs/libjpeg-turbo
+	>=media-libs/libmypaint-1.3.0:=
+	media-libs/libpng:=
+	media-libs/opencv
+	>=sci-libs/superlu-4.1:=
+	sys-libs/zlib
+	virtual/cblas
+	virtual/libusb:1
+	virtual/opengl
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+CMAKE_USE_DIR="${S}/toonz/sources"
+
+src_configure() {
+	local mycmakeargs=(
+		-DTIFF_LIBRARY="${S}/thirdparty/tiff-4.0.3/libtiff/.libs/libtiff.a"
+		-DSUPERLU_INCLUDE_DIR="${EPREFIX}/usr/include/superlu"
+		-DLZO_INCLUDE_DIR="${EPREFIX}/usr/include/lzo"
+		-DCMAKE_SKIP_RPATH=ON
+		-DWITH_TRANSLATION=OFF # Workaround issue #4840
+	)
+
+	# The upstream uses their own modified libtiff
+	# See: https://github.com/opentoonz/opentoonz/blob/master/doc/how_to_build_linux.md#building-libtiff
+	cd "thirdparty/tiff-4.0.3" || die
+	econf \
+		--with-pic \
+		--disable-jbig \
+		--enable-static \
+		--disable-shared
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cd "${S}/thirdparty/tiff-4.0.3" || die
+	emake
+	cmake_src_compile
+}
diff --git a/media-gfx/opentoonz/opentoonz-9999.ebuild b/media-gfx/opentoonz/opentoonz-9999.ebuild
index 08ff383..0c80381 100644
--- a/media-gfx/opentoonz/opentoonz-9999.ebuild
+++ b/media-gfx/opentoonz/opentoonz-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -60,6 +60,7 @@ src_configure() {
 		-DSUPERLU_INCLUDE_DIR="${EPREFIX}/usr/include/superlu"
 		-DLZO_INCLUDE_DIR="${EPREFIX}/usr/include/lzo"
 		-DCMAKE_SKIP_RPATH=ON
+		-DWITH_TRANSLATION=OFF # Workaround issue #4840
 	)
 
 	# The upstream uses their own modified libtiff