patch 8.1.0428: the :suspend command is not tested

Problem:    The :suspend command is not tested.
Solution:   Add a test. (Dominique Pelle, closes #3472)

src/Make_all.mak

@@ -168,6 +168,7 @@ NEW_TESTS = \
 	test_stat \
 	test_statusline \
 	test_substitute \
+	test_suspend \
 	test_swap \
 	test_syn_attr \
 	test_syntax \

src/testdir/test_alot.vim

@@ -52,6 +52,7 @@ source test_set.vim
 source test_sort.vim
 source test_sha256.vim
 source test_statusline.vim
+source test_suspend.vim
 source test_syn_attr.vim
 source test_tabline.vim
 source test_tabpage.vim

src/testdir/test_suspend.vim

@@ -0,0 +1,51 @@
+" Test :suspend
+
+source shared.vim
+
+func Test_suspend()
+  if !has('terminal') || !executable('/bin/sh')
+    return
+  endif
+
+  let buf = term_start('/bin/sh')
+  " Wait for shell prompt.
+  call WaitForAssert({-> assert_match('$ $', term_getline(buf, '.'))})
+
+  call term_sendkeys(buf, v:progpath
+        \               . " --clean -X"
+        \               . " -c 'set nu'"
+        \               . " -c 'call setline(1, \"foo\")'"
+        \               . " Xfoo\<CR>")
+  " Cursor in terminal buffer should be on first line in spawned vim.
+  call WaitForAssert({-> assert_equal('  1 foo', term_getline(buf, '.'))})
+
+  for suspend_cmd in [":suspend\<CR>",
+        \             ":stop\<CR>",
+        \             ":suspend!\<CR>",
+        \             ":stop!\<CR>",
+        \             "\<C-Z>"]
+    " Suspend and wait for shell prompt.
+    call term_sendkeys(buf, suspend_cmd)
+    call WaitForAssert({-> assert_match('$ $', term_getline(buf, '.'))})
+
+    " Without 'autowrite', buffer should not be written.
+    call assert_equal(0, filereadable('Xfoo'))
+
+    call term_sendkeys(buf, "fg\<CR>")
+    call WaitForAssert({-> assert_equal('  1 foo', term_getline(buf, '.'))})
+  endfor
+
+  " Test that :suspend! with 'autowrite' writes content of buffers if modified.
+  call term_sendkeys(buf, ":set autowrite\<CR>")
+  call assert_equal(0, filereadable('Xfoo'))
+  call term_sendkeys(buf, ":suspend\<CR>")
+  " Wait for shell prompt.
+  call WaitForAssert({-> assert_match('$ $', term_getline(buf, '.'))})
+  call assert_equal(['foo'], readfile('Xfoo'))
+  call term_sendkeys(buf, "fg\<CR>")
+  call WaitForAssert({-> assert_equal('  1 foo', term_getline(buf, '.'))})
+
+  exe buf . 'bwipe!'
+  call delete('Xfoo')
+  set autowrite&
+endfunc

src/version.c

@@ -794,6 +794,8 @@ static char *(features[]) =
 
 static int included_patches[] =
 {   /* Add new patch number below this line */
+/**/
+    428,
 /**/
     427,
 /**/