flewkey/flewkey-overlay
1
0
Fork 0
Code Releases Activity

x11-drivers/displaylink-driver: add 5.7.0.61.129

Browse Source
This commit is contained in:
Ryan Fox 2023-07-22 12:22:58 -07:00
parent e5d0aa9f62
commit 50a8cb24f0
Signed by: flewkey
GPG Key ID: 94F56ADFD848851E
2 changed files with 84 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
x11-drivers/displaylink-driver/Manifest
View File

@ -1 +1,2 @@
DIST displaylink-driver-5.6.1.59.184.zip 16905857 BLAKE2B 2eb15bbf21802eaed0408fa218993fbbd07b92c8c313b39fde9f9a8961b96e75ed15902c20e66fb68b3c41e4abbe03c6224547a98cbde3250c3507bace94130d SHA512 1a52db6ebe78ead91ae1e62a5242977c85165f71196e7ac9ea2cb0964d1988fed47d23832a0e30112a6b254fbb54626dfb43b13d05bc47eee9d0ebbe242612fb
DIST displaylink-driver-5.7.0.61.129.zip 17130641 BLAKE2B 1ddc21668e5b0259485c1c21749d315f1683f41b6bfdb3a3058d0df4d77bef69d002e215b7e3d18bd0a107c3ad65656cece8f130a2daf6bbfc443d9f6459e8e4 SHA512 f98aa404ea80845674adafa24aa3b40db71c5c4a75dfab3682fd1834205ed20a4561dcd014b930983ee60f53f518c1276c0adab20df89d464abc9e895412709a

83
x11-drivers/displaylink-driver/displaylink-driver-5.7.0.61.129.ebuild Normal file
View File

@ -0,0 +1,83 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit udev systemd
AR_DATE="2023-04"
AR_NAME="DisplayLink%20USB%20Graphics%20Software%20for%20Ubuntu5.7-EXE.zip"
UBUNTU_VER="1604"
MY_PV=$(ver_rs 3 '-')
MY_P="${PN}-${MY_PV}"
S="${WORKDIR}/${MY_P}"
SRC_URI="https://www.synaptics.com/sites/default/files/exe_files/${AR_DATE}/${AR_NAME} -> ${P}.zip"
KEYWORDS="~amd64"
DESCRIPTION="Driver for modern DisplayLink devices"
HOMEPAGE="http://www.displaylink.com/downloads/ubuntu"
LICENSE="DisplayLink-EULA"
SLOT="0"
IUSE="systemd"
DEPEND="app-arch/unzip"
RDEPEND="
virtual/libusb
virtual/udev
x11-libs/libevdi
"
QA_PREBUILT="opt/displaylink/DisplayLinkManager"
src_unpack() {
default
sh "${WORKDIR}/${MY_P}.run" --noexec --keep
}
src_prepare() {
default
source "${S}/udev-installer.sh" && create_udev_rules_file "${S}/99-dlm.rules"
source "${S}/udev-installer.sh" && displaylink_bootstrapper_code > "${S}/udev.sh"
if use systemd; then
sed -i '/^ chmod.*displaylink-driver.service/d' "${S}/displaylink-installer.sh"
sed -i 's;^ cat > /.*/displaylink-driver.service <<EOF; cat <<EOF;' "${S}/displaylink-installer.sh"
sed -i '/^if.*$(id -u).*then/i return' "${S}/displaylink-installer.sh"
source "${S}/udev-installer.sh" && systemd_start_stop_functions >> "${S}/udev.sh"
source "${S}/displaylink-installer.sh" && add_systemd_service > "${S}/displaylink-driver.service"
else
cat "${FILESDIR}/openrc_start_stop_functions" >> "${S}/udev.sh"
fi
source "${S}/udev-installer.sh" && create_main_function >> "${S}/udev.sh"
}
src_install() {
exeinto "/opt/displaylink"
insinto "/opt/displaylink"
case "${ARCH}" in
amd64) MY_ARCH="x64" ;;
*) MY_ARCH="${ARCH}" ;;
esac
ARCH_DIR="${S}/${MY_ARCH}-ubuntu-${UBUNTU_VER}"
doexe "${ARCH_DIR}/DisplayLinkManager"
doins "${S}/ella-dock-release.spkg"
doins "${S}/firefly-monitor-release.spkg"
doins "${S}/ridge-dock-release.spkg"
if use systemd; then
systemd_dounit "${S}/displaylink-driver.service"
else
newinitd "${FILESDIR}/dlm.init.d" "dlm"
fi
udev_dorules "${S}/99-dlm.rules"
insopts -m744
doins "${S}/udev.sh"
}
pkg_postinst() {
udev_reload
}
pkg_postrm() {
udev_reload
}