app-text/komikku: add 1.37.1, move to Codeberg

app-text/komikku/Manifest

@@ -1,2 +1,3 @@
 DIST komikku-1.31.0.tar.bz2 3403924 BLAKE2B 1c346e42b7077e09a04d524506bb2cd0d69d6b68964c25a710434959bfe8dfc90113be3699588ae7faf910bdf252808dbd00cf7f4cb0941ef4f8f90a2aed5959 SHA512 b36b066bdc52e2544481a582060166c747024def99d142f32e5ffc290bc243541f2cbce7b222fc05483ecca0489ecf6a2c8d8e9401edfb32b1aa3c5e2b68abdd
 DIST komikku-1.33.0.tar.bz2 3400942 BLAKE2B 35d764f914074dbc3b7e4f2ee828be9e4c80d48812d8ef9b94684d6eb9177779a7ae306abeb6a9fb3106ab9db880693fdf90f7be05b1bececbeecd8feb51fc17 SHA512 3996300e12081cc2cd27310dcb0f5083348c72e62a7cce02c1b1c93c875d0ac0cfc708520149b511af19e46da65ec96b3936893aeb8e7abe2960d02f0e1e72af
+DIST komikku-1.37.1.tar.gz 3837412 BLAKE2B f89eb63842808e6cfe7c02f7b3053669754cff7aedba709d51917f19baff8473af7464460d587b90574a459c3bf99533ccf5d08d6227ee17847a9fd6450d36fe SHA512 72b7352e2d57c0e68f0203a6aa98aa355346c75f6278bac22e16ecad1631fcc64338441865428d36438698d384dbd7cd1aeaab5257466ccc5fbde9ea73e336dd

app-text/komikku/komikku-1.37.1.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite(+),ssl(+)"
+DISTUTILS_USE_PEP517=no
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1 meson gnome2-utils xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/valos/Komikku.git"
+else
+	S="${WORKDIR}/${PN}"
+	SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An online/offline manga reader for GNOME"
+HOMEPAGE="https://gitlab.com/valos/Komikku"
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	>=gui-libs/gtk-4.10:4
+	>=gui-libs/libadwaita-1.3:1[introspection]
+	net-libs/webkit-gtk:6[introspection]
+"
+RDEPEND="
+	${DEPEND}
+	$(python_gen_cond_dep '
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/colorthief[${PYTHON_USEDEP}]
+		dev-python/cffi[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/dateparser[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-python/piexif[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pure-protobuf[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		dev-python/rarfile[compressed,${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+"
+
+src_install() {
+	meson_src_install
+	python_optimize
+	python_fix_shebang "${D}/usr/bin/komikku"
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}

app-text/komikku/komikku-9999.ebuild

@@ -11,12 +11,10 @@ inherit distutils-r1 meson gnome2-utils xdg
 
 if [[ ${PV} == 9999 ]]; then
 	inherit git-r3
-	EGIT_REPO_URI="https://gitlab.com/valos/Komikku.git"
+	EGIT_REPO_URI="https://codeberg.org/valos/Komikku.git"
 else
-	MY_PN="${PN^}"
-	MY_P="${MY_PN}-v${PV}"
-	S="${WORKDIR}/${MY_P}"
-	SRC_URI="https://gitlab.com/valos/Komikku/-/archive/v${PV}/${MY_P}.tar.bz2 -> ${P}.tar.bz2"
+	S="${WORKDIR}/${PN}"
+	SRC_URI="https://codeberg.org/valos/Komikku/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64"
 fi
 

app-text/komikku/metadata.xml

@@ -6,6 +6,7 @@
 		<name>Ryan Fox</name>
 	</maintainer>
 	<upstream>
+		<remote-id type="codeberg">valos/Komikku</remote-id>
 		<remote-id type="gitlab">valos/Komikku</remote-id>
 	</upstream>
 </pkgmetadata>