mirror of
https://git.zap.org.au/git/trader.git
synced 2024-10-27 18:20:13 -04:00
d07dc71f1b
These files have been created by running ./build-aux/bootstrap with Gnulib as at commit f9b39c4e337f1dc0dd07c4f3985c476fb875d799 (with a date stamp of Sun Jul 31 23:28:18 2022 +0200), Autoconf 2.71, Automake 1.16.5, Gettext 0.21 and pkgconf 1.8.0.
61 lines
2.0 KiB
Plaintext
61 lines
2.0 KiB
Plaintext
# iconv_open.m4 serial 16
|
|
dnl Copyright (C) 2007-2022 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_FUNC_ICONV_OPEN],
|
|
[
|
|
AC_REQUIRE([AM_ICONV])
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
AC_REQUIRE([gl_ICONV_H_DEFAULTS])
|
|
if test "$am_cv_func_iconv" = yes; then
|
|
dnl Provide the <iconv.h> override, for the sake of the C++ aliases.
|
|
gl_REPLACE_ICONV_H
|
|
dnl Test whether iconv_open accepts standardized encoding names.
|
|
dnl We know that GNU libiconv and GNU libc do.
|
|
AC_EGREP_CPP([gnu_iconv], [
|
|
#include <iconv.h>
|
|
#if defined _LIBICONV_VERSION || (defined __GLIBC__ && !defined __UCLIBC__)
|
|
gnu_iconv
|
|
#endif
|
|
], [gl_func_iconv_gnu=yes], [gl_func_iconv_gnu=no])
|
|
if test $gl_func_iconv_gnu = no; then
|
|
iconv_flavor=
|
|
case "$host_os" in
|
|
aix*) iconv_flavor=ICONV_FLAVOR_AIX ;;
|
|
irix*) iconv_flavor=ICONV_FLAVOR_IRIX ;;
|
|
hpux*) iconv_flavor=ICONV_FLAVOR_HPUX ;;
|
|
osf*) iconv_flavor=ICONV_FLAVOR_OSF ;;
|
|
solaris*) iconv_flavor=ICONV_FLAVOR_SOLARIS ;;
|
|
openedition*) iconv_flavor=ICONV_FLAVOR_ZOS ;;
|
|
esac
|
|
if test -n "$iconv_flavor"; then
|
|
AC_DEFINE_UNQUOTED([ICONV_FLAVOR], [$iconv_flavor],
|
|
[Define to a symbolic name denoting the flavor of iconv_open()
|
|
implementation.])
|
|
gl_REPLACE_ICONV_OPEN
|
|
fi
|
|
fi
|
|
m4_ifdef([gl_FUNC_ICONV_OPEN_UTF_SUPPORT], [
|
|
gl_FUNC_ICONV_OPEN_UTF_SUPPORT
|
|
case "$gl_cv_func_iconv_supports_utf" in
|
|
*yes) ;;
|
|
*)
|
|
REPLACE_ICONV_UTF=1
|
|
AC_DEFINE([REPLACE_ICONV_UTF], [1],
|
|
[Define if the iconv() functions are enhanced to handle the UTF-{16,32}{BE,LE} encodings.])
|
|
REPLACE_ICONV=1
|
|
gl_REPLACE_ICONV_OPEN
|
|
;;
|
|
esac
|
|
])
|
|
fi
|
|
])
|
|
|
|
AC_DEFUN([gl_REPLACE_ICONV_OPEN],
|
|
[
|
|
gl_REPLACE_ICONV_H
|
|
REPLACE_ICONV_OPEN=1
|
|
])
|