trader/configure.ac

dnl *********************************************************************
dnl *                                                                   *
dnl *           Star Traders: A Game of Interstellar Trading            *
dnl *              Copyright (C) 1990-2024, John Zaitseff               *
dnl *                                                                   *
dnl *********************************************************************
dnl
dnl Author: John Zaitseff <J.Zaitseff@zap.org.au>
dnl SPDX-License-Identifier: GPL-3.0-or-later
dnl $Id$
dnl
dnl This file, configure.ac, contains information required by autoconf to
dnl generate the corresponding configure script.
dnl
dnl
dnl This program is free software: you can redistribute it and/or modify
dnl it under the terms of the GNU General Public License as published by
dnl the Free Software Foundation, either version 3 of the License, or (at
dnl your option) any later version.
dnl
dnl This program is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl General Public License for more details.
dnl
dnl You should have received a copy of the GNU General Public License
dnl along with this program.  If not, see https://www.gnu.org/licenses/.


AC_INIT([Star Traders], [7.21], [J.Zaitseff@zap.org.au], [trader],
	[https://www.zap.org.au/projects/trader/])
AC_DEFINE([PACKAGE_AUTHOR], ["John Zaitseff"], [Package author])

AC_PREREQ([2.71])
AC_CONFIG_MACRO_DIRS([m4])
AC_CONFIG_SRCDIR([src/trader.c])
AC_CONFIG_AUX_DIR([build-aux])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([1.16 -Wall -Werror foreign dist-xz])
AM_MAINTAINER_MODE([enable])
AC_CONFIG_LIBOBJ_DIR([lib])

AC_PROG_CC
AS_CASE(["$ac_prog_cc_stdc"],
	[c17|c11|c99], [], [
	AC_MSG_ERROR([requires an ISO/IEC 9899:1999 (C99) compiler])
])

gl_EARLY

AX_CFLAGS_WARN_ALL
AX_C___ATTRIBUTE__
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T

AM_GNU_GETTEXT([external], [need-ngettext])
AM_GNU_GETTEXT_VERSION([0.21])

gl_INIT

AS_IF([test "x$ac_cv_header_monetary_h" != xyes], [
	AC_MSG_ERROR([requires <monetary.h> to exist in the C library])
])

USE_LATEST_XOPEN_SOURCE
AS_IF([test "x$x_cv_latest_xopen_source" = xunknown], [
	AC_MSG_ERROR([requires X/Open SUSv4/XPG7 or SUSv3/XPG6])
])

AX_WITH_CURSES
AS_IF([test "x$ax_cv_curses" != xyes || test "x$ax_cv_curses_color" != xyes], [
	AC_MSG_ERROR([requires an X/Open-compatible Curses library with colour])
])
AS_IF([test "x$ax_cv_curses_enhanced" = xyes], [],
      [test "x$USE_NLS" = xyes], [
	AC_MSG_WARN([no X/Open-compatible Enhanced Curses library found

*****************    Locales with multibyte character sequences (such as
***  WARNING  ***    UTF-8) require a wide-character version of Curses,
*****************    such as NcursesW, to work correctly.
])
])

AC_SUBST([desktopdir],['${datadir}/applications'])
AC_SUBST([metainfodir],['${datadir}/metainfo'])
AC_SUBST([iconsdir],['${datadir}/icons/hicolor'])

AC_CONFIG_FILES([
	Makefile
	lib/Makefile
	src/Makefile
	data/Makefile
	doc/Makefile
	po/Makefile.in
	m4/Makefile
])
AC_OUTPUT

AC_MSG_NOTICE([

  Configuration summary for AC_PACKAGE_NAME AC_PACKAGE_VERSION:

  Building for host:                $host
  Using C compiler with options:    $CC $CFLAGS
  Installation prefix:              $prefix
  Native Language Support enabled:  $USE_NLS
  Curses library selected:          $ax_cv_curses_which
])
Add the basic infrastructure required by autoconf and automake 2011-06-14 08:16:26 -04:00			`dnl *********************************************************************`
			`dnl * *`
			`dnl * Star Traders: A Game of Interstellar Trading *`
Update the copyright year to 2024 2024-01-01 20:33:37 -05:00			`dnl * Copyright (C) 1990-2024, John Zaitseff *`
Add the basic infrastructure required by autoconf and automake 2011-06-14 08:16:26 -04:00			`dnl * *`
			`dnl *********************************************************************`
			`dnl`
Remove superfluous version and date information 2011-06-14 09:01:15 -04:00			`dnl Author: John Zaitseff <J.Zaitseff@zap.org.au>`
Add SPDX licence identifiers to all source code files 2024-05-25 16:05:27 -04:00			`dnl SPDX-License-Identifier: GPL-3.0-or-later`
Add the basic infrastructure required by autoconf and automake 2011-06-14 08:16:26 -04:00			`dnl $Id$`
			`dnl`
			`dnl This file, configure.ac, contains information required by autoconf to`
			`dnl generate the corresponding configure script.`
			`dnl`
			`dnl`
			`dnl This program is free software: you can redistribute it and/or modify`
			`dnl it under the terms of the GNU General Public License as published by`
			`dnl the Free Software Foundation, either version 3 of the License, or (at`
			`dnl your option) any later version.`
			`dnl`
			`dnl This program is distributed in the hope that it will be useful,`
			`dnl but WITHOUT ANY WARRANTY; without even the implied warranty of`
			`dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU`
			`dnl General Public License for more details.`
			`dnl`
			`dnl You should have received a copy of the GNU General Public License`
Change all relevant http references to https (secure HTTP) 2018-03-29 21:46:37 -04:00			`dnl along with this program. If not, see https://www.gnu.org/licenses/.`
Add the basic infrastructure required by autoconf and automake 2011-06-14 08:16:26 -04:00
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00
Start preparing for version 7.21 2024-01-30 22:26:08 -05:00			`AC_INIT([Star Traders], [7.21], [J.Zaitseff@zap.org.au], [trader],`
Move to the new ZAP Group website structure 2019-11-07 04:21:34 -05:00			`[https://www.zap.org.au/projects/trader/])`
Rework the input to autoconf and add checks for the C compiler Rewrite the input to autoconf: add the definition of PACKAGE_AUTHOR, add checks for Standard C and for C compiler warnings (via the file m4/ax_cflags_warn_all.m4 from the GNU Autoconf Archive), rearrange various macros and the order of Makefile creation. 2011-06-23 08:43:31 -04:00			`AC_DEFINE([PACKAGE_AUTHOR], ["John Zaitseff"], [Package author])`
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00
Update minimum version of Autoconf to allow C17 or C11 compilation 2022-07-31 20:01:41 -04:00			`AC_PREREQ([2.71])`
Update to the latest version of Gnulib Specify ACLOCAL_AMFLAGS as otherwise the current Python version of gnulib-tool fails with "IndexError: list index out of range". 2024-05-20 14:36:37 -04:00			`AC_CONFIG_MACRO_DIRS([m4])`
Rework the input to autoconf and add checks for the C compiler Rewrite the input to autoconf: add the definition of PACKAGE_AUTHOR, add checks for Standard C and for C compiler warnings (via the file m4/ax_cflags_warn_all.m4 from the GNU Autoconf Archive), rearrange various macros and the order of Makefile creation. 2011-06-23 08:43:31 -04:00			`AC_CONFIG_SRCDIR([src/trader.c])`
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00			`AC_CONFIG_AUX_DIR([build-aux])`
Move AC_CONFIG_HEADERS macro to the top of the file The top of the file is where the macro should have been defined in the first place. 2011-07-26 05:57:13 -04:00			`AC_CONFIG_HEADERS([config.h])`
Update to Gettext 0.21 and Automake 1.16 2024-01-01 21:00:02 -05:00			`AM_INIT_AUTOMAKE([1.16 -Wall -Werror foreign dist-xz])`
Enable maintainer mode in configure.ac Although maintainer mode is the default, explicitly listing in configure.ac allows users (or distributions, more to the point) of disabling it by passing "--disable-maintainer-mode" to ./configure. 2017-05-19 19:06:00 -04:00			`AM_MAINTAINER_MODE([enable])`
Rework the input to autoconf and add checks for the C compiler Rewrite the input to autoconf: add the definition of PACKAGE_AUTHOR, add checks for Standard C and for C compiler warnings (via the file m4/ax_cflags_warn_all.m4 from the GNU Autoconf Archive), rearrange various macros and the order of Makefile creation. 2011-06-23 08:43:31 -04:00			`AC_CONFIG_LIBOBJ_DIR([lib])`
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00
			`AC_PROG_CC`
Update minimum version of Autoconf to allow C17 or C11 compilation 2022-07-31 20:01:41 -04:00			`AS_CASE(["$ac_prog_cc_stdc"],`
			`[c17\|c11\|c99], [], [`
Complete rewrite of the M4 macro that checks for Curses 2011-07-28 07:19:33 -04:00			`AC_MSG_ERROR([requires an ISO/IEC 9899:1999 (C99) compiler])`
			`])`
Add an explicit check for a C99 compiler We use C99 features quite extensively in the source code. 2011-07-26 07:13:12 -04:00
Add support for the Gnulib portability library In particular, the gnulib-tool utility now maintains lib/Makefile.am, as well as many files in the m4 and lib directories. The file m4/gnulib-cache.m4 allows the Gnulib files to be refreshed. See http://www.gnu.org/software/gnulib/. 2011-07-23 03:19:07 -04:00			`gl_EARLY`

Rework the input to autoconf and add checks for the C compiler Rewrite the input to autoconf: add the definition of PACKAGE_AUTHOR, add checks for Standard C and for C compiler warnings (via the file m4/ax_cflags_warn_all.m4 from the GNU Autoconf Archive), rearrange various macros and the order of Makefile creation. 2011-06-23 08:43:31 -04:00			`AX_CFLAGS_WARN_ALL`
Add the __attribute__((noreturn)) function specifier where possible 2011-06-30 02:09:13 -04:00			`AX_C___ATTRIBUTE__`
Add some more checks for the C compiler/environment 2011-07-22 00:19:05 -04:00			`AC_TYPE_SIZE_T`
			`AC_TYPE_SSIZE_T`

Specify that ngettext() is used in the program 2018-07-24 07:25:37 -04:00			`AM_GNU_GETTEXT([external], [need-ngettext])`
Update to Gettext 0.21 and Automake 1.16 2024-01-01 21:00:02 -05:00			`AM_GNU_GETTEXT_VERSION([0.21])`
Convert strings to UTF-8 if possible during file save and load 2011-08-07 21:15:44 -04:00
Add support for the Gnulib portability library In particular, the gnulib-tool utility now maintains lib/Makefile.am, as well as many files in the m4 and lib directories. The file m4/gnulib-cache.m4 allows the Gnulib files to be refreshed. See http://www.gnu.org/software/gnulib/. 2011-07-23 03:19:07 -04:00			`gl_INIT`

Add the Gnulib monetary module to check for the existence of <monetary.h> 2018-08-07 19:57:25 -04:00			`AS_IF([test "x$ac_cv_header_monetary_h" != xyes], [`
			`AC_MSG_ERROR([requires <monetary.h> to exist in the C library])`
			`])`

Move redefinition of _XOPEN_SOURCE into its own Autoconf macro and header This makes the main source code look a little cleaner, at the expense of background magic happening in the configure-generated config.h. But this magic was already happening for _GNU_SOURCE, __EXTENSIONS__ and the like. The only wrinkle is that newer versions of NcursesW cause ./configure to include "-D_XOPEN_SOURCE=600" as part of the compilation command line--on systems that support _XOPEN_SOURCE=700. The AC_DEFINE/AC_DEFINE_UNQUOTED macros automatically comment out any "#undef" lines in config.h, so the file lib/xopen_source.h works around this limitation. It is automatically included by config.h. 2018-08-09 04:05:39 -04:00			`USE_LATEST_XOPEN_SOURCE`
			`AS_IF([test "x$x_cv_latest_xopen_source" = xunknown], [`
			`AC_MSG_ERROR([requires X/Open SUSv4/XPG7 or SUSv3/XPG6])`
			`])`

Add the SysV-compatible curses library The AX_WITH_CURSES macro is taken from the autoconf-archive project, available at http://www.gnu.org/software/autoconf-archive/. 2011-06-30 06:31:19 -04:00			`AX_WITH_CURSES`
Complete rewrite of the M4 macro that checks for Curses 2011-07-28 07:19:33 -04:00			`AS_IF([test "x$ax_cv_curses" != xyes \|\| test "x$ax_cv_curses_color" != xyes], [`
			`AC_MSG_ERROR([requires an X/Open-compatible Curses library with colour])`
			`])`
Warn about enhanced Curses only if NLS is enabled If Native Language Support is disabled, the program does not use the GNU Gettext library and thus all strings are in ASCII format: enhanced Curses is not needed in such situations. 2018-07-25 01:04:59 -04:00			`AS_IF([test "x$ax_cv_curses_enhanced" = xyes], [],`
			`[test "x$USE_NLS" = xyes], [`
Warn if NcursesW (or similar) is not found Add a prominent warning if NcursesW (or some other wide-character version of Curses) is not found at build time. It is not an error because the game might be run under a single-byte encoding (eg, ISO8859-1), even if compiled under a multibyte encoding (eg, UTF-8). 2012-03-27 20:08:38 -04:00			`AC_MSG_WARN([no X/Open-compatible Enhanced Curses library found`

			`***************** Locales with multibyte character sequences (such as`
			`* WARNING * UTF-8) require a wide-character version of Curses,`
			`***************** such as NcursesW, to work correctly.`
			`])`
			`])`
Add the SysV-compatible curses library The AX_WITH_CURSES macro is taken from the autoconf-archive project, available at http://www.gnu.org/software/autoconf-archive/. 2011-06-30 06:31:19 -04:00
Generate trader.desktop and install it in the correct location 2017-05-17 06:12:44 -04:00			`AC_SUBST([desktopdir],['${datadir}/applications'])`
Rename and update desktop and AppStream data files and utilities Rename the desktop and AppStream data files to conform to the AppStream 1.0 specification; these now have names based on "au.org.zap.trader". Add a caption to the AppStream screenshot; update all translations to suit. Rename msgfmt-appdata to msgfmt-metainfo to reflect these changes. 2024-01-03 03:34:25 -05:00			`AC_SUBST([metainfodir],['${datadir}/metainfo'])`
Make sure the icon images are distributed and installed correctly 2017-05-19 09:54:56 -04:00			`AC_SUBST([iconsdir],['${datadir}/icons/hicolor'])`
Generate trader.desktop and install it in the correct location 2017-05-17 06:12:44 -04:00
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00			`AC_CONFIG_FILES([`
			`Makefile`
			`lib/Makefile`
Rework the input to autoconf and add checks for the C compiler Rewrite the input to autoconf: add the definition of PACKAGE_AUTHOR, add checks for Standard C and for C compiler warnings (via the file m4/ax_cflags_warn_all.m4 from the GNU Autoconf Archive), rearrange various macros and the order of Makefile creation. 2011-06-23 08:43:31 -04:00			`src/Makefile`
Add a data directory for non-code data 2016-03-11 00:47:14 -05:00			`data/Makefile`
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00			`doc/Makefile`
Add preliminary support for GNU gettext internationalisation 2011-08-01 04:17:02 -04:00			`po/Makefile.in`
Add an automake Makefile for the m4 macro directory 2011-06-15 20:49:55 -04:00			`m4/Makefile`
Add build infrastructure for basic processing of various subdirectories 2011-06-14 08:55:48 -04:00			`])`
Add the basic infrastructure required by autoconf and automake 2011-06-14 08:16:26 -04:00			`AC_OUTPUT`
Print a configuration summary at the end of configure 2018-07-25 01:10:08 -04:00
			`AC_MSG_NOTICE([`

Tweak configuration summary to include the compiler used with flags 2018-08-05 22:37:32 -04:00			`Configuration summary for AC_PACKAGE_NAME AC_PACKAGE_VERSION:`
Print a configuration summary at the end of configure 2018-07-25 01:10:08 -04:00
			`Building for host: $host`
Tweak configuration summary to include the compiler used with flags 2018-08-05 22:37:32 -04:00			`Using C compiler with options: $CC $CFLAGS`
Print a configuration summary at the end of configure 2018-07-25 01:10:08 -04:00			`Installation prefix: $prefix`
			`Native Language Support enabled: $USE_NLS`
			`Curses library selected: $ax_cv_curses_which`
			`])`