From 435134c3544c016ce8cf14a0baaf571670bfa653 Mon Sep 17 00:00:00 2001
From: Karl Heyes <karl@xiph.org>
Date: Sat, 30 Jul 2005 17:09:51 +0000
Subject: [PATCH] initial openssl check

svn path=/icecast/trunk/m4/; revision=9655
---
 m4/xiph_openssl.m4 | 49 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 m4/xiph_openssl.m4

diff --git a/m4/xiph_openssl.m4 b/m4/xiph_openssl.m4
new file mode 100644
index 00000000..f62a5244
--- /dev/null
+++ b/m4/xiph_openssl.m4
@@ -0,0 +1,49 @@
+dnl XIPH_PATH_OPENSSL([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
+dnl Karl Heyes <karl@xiph.org>
+dnl Test for openssl, and define OPENSSL_CFLAGS and OPENSSL_LIBS
+dnl
+AC_DEFUN([XIPH_PATH_OPENSSL],
+[dnl 
+dnl Get the cflags and libraries
+dnl
+AC_ARG_WITH(openssl,
+    AC_HELP_STRING([--with-openssl=PFX],[Prefix where openssl is installed (optional)]),
+    openssl_prefix="$withval", openssl_prefix="")
+
+if test "x$openssl_prefix" != "x" -a "x$openssl_prefix" != "xyes"; then
+    OPENSSL_LIBS="-L$openssl_prefix/lib -lssl"
+    OPENSSL_CFLAGS="-I$openssl_prefix/include"
+else
+    AC_PATH_PROG([PKGCONFIG], [pkg-config], [no])
+    if test "$PKGCONFIG" != "no" && `$PKGCONFIG --exists openssl`; then
+        OPENSSL_CFLAGS=`$PKGCONFIG --cflags openssl`
+        OPENSSL_LIBS=`$PKGCONFIG --libs openssl`
+    else
+        if test "x$prefix" = "xNONE"; then
+            openssl_prefix="/usr/local"
+        else
+            openssl_prefix="$prefix"
+        fi
+        OPENSSL_LIBS="-L$openssl_prefix/lib -lssl"
+        OPENSSL_CFLAGS="-I$openssl_prefix/include"
+    fi
+fi
+
+# Now try linking to openssl
+xt_save_CFLAGS="$CFLAGS"
+xt_save_LIBS="$LIBS"
+CFLAGS="$CFLAGS $OPENSSL_CFLAGS"
+LIBS="$OPENSSL_LIBS $LIBS"
+AC_TRY_LINK([#include <openssl/ssl.h>], [void *a = SSL_new], [openssl_ok='yes'])
+CFLAGS="$xt_save_CFLAGS"
+LIBS="$xt_save_LIBS"
+
+if test "$openssl_ok" = "yes"; then
+    AC_DEFINE(HAVE_OPENSSL, 1, [Define if you have libopenssl.])
+    ifelse([$1], , :, [$1])     
+else
+    OPENSSL_LIBS=""
+    OPENSSL_CFLAGS=""
+    ifelse([$2], , :, [$2])
+fi
+])